-- Morpher_Up_Down
-- Dani Rosen, June 2006
-- 
-- moves the Morpher modifier on all heads named "Face_0" up and
-- down the stack, above and below Phyique. Below - for Max editing,
-- Above - for game export.
--
-- v1.1 - Jul 28, 2006 - made it work with decorator heads, converted to macro.
-- v1.2 - Aug 3, 2006 - fixed decorator head support

macroScript Morpher_Up_Down
	category:"DaniTools" 
	internalcategory:"DaniTools"
	tooltip:"Morpher Up-Down"
	buttontext:"Morpher Up-Down"
	Icon:#("SubObjectIcons",31)
(


global faces = #()
for i in objects do
(
	if (matchpattern i.name pattern:"*Face_0") then append faces i
)

rollout MUD "Morpher Up-Down  v1.2"
(
	button MU "Morphers Up" width:90 across:2 
	button MD "Morphers Down" width:90
	
	on MU pressed do
	(
		for m in faces do
		(
			try
			(
				if (modpanel.getModifierIndex m m.Morpher) == 2 then
				(
					addmodifier m (m.Morpher)
					deletemodifier m 3
				)
			) catch (
				try
				(
					select m
					messagebox ("The selected \"" + m.name + "\" is missing a Morpher modifer.\n" + \
					"Please add one and then continue") title:"Missing Morpher"
				) catch (
					messagebox "Current scene has changed since this tool was opened.\n Please close and reopen"
				)
			)
		)
	)
	
	on MD pressed do
	(
		for m in faces do
		(
			try
			(
				if (modpanel.getModifierIndex m m.Morpher) == 1 then
				(
					addmodifier m (m.Morpher) before:2
					deletemodifier m 1
				)
			) catch (
				try
				(
					select m
					messagebox ("The selected \"" + m.name + "\" is missing a Morpher modifer.\n" + \
					"Please add one and then continue") title:"Missing Morpher"
				) catch (
					messagebox "Current scene has changed since this tool was opened.\n Please close and reopen"
				)
			)
		)	
	)
	
)
createdialog MUD 220 40

)